Cách tách số trong 1 ô Excel

Bạn có thể dùng các hàm văn bản LEFT, MID, RIGHT, SEARCH và LEN để điều khiển các chuỗi văn bản trong dữ liệu của mình. Ví dụ, bạn có thể phân phối họ, tên, tên đệm từ một ô đơn thành ba cột riêng biệt.

Điểm mấu chốt để phân phối các cấu phần tên bằng hàm văn bản là vị trí của mỗi ký tự trong một chuỗi văn bản. Vị trí của các khoảng trắng trong chuỗi văn bản cũng rất quan trọng vì chúng cho biết phần đầu hoặc phần cuối của tên trong một chuỗi.

Ví dụ, trong một ô chỉ chứa họ và tên, họ bắt đầu sau lần xuất hiện đầu tiên của một khoảng trắng. Một số tên trong danh sách của bạn có thể chứa tên đệm, trong trường hợp này họ bắt đầu sau thể hiện khoảng trắng thứ hai.

Bài viết này hướng dẫn bạn cách trích xuất các cấu phần khác nhau từ nhiều định dạng tên khác nhau bằng cách dùng các hàm tiện dụng này. Bạn cũng có thể tách văn bản thành các cột khác nhau bằng Trình hướng dẫn Chuyển Văn bản thành Cột

Tên ví dụ

Mô tả

Tên

Tên đệm

Họ

Suffix

Jeff Smith

Không có tên đệm

Jeff

Smith

Eric S. Kurjan

Một tên viết tắt giữa

Eric

Tiếng Kurjan

Janaina B. G. Bueno

Hai tên viết tắt giữa

Janaina

B. G.

Bueno

Kabul, Wendy Beth

Họ trước tiên, với dấu phẩy

Wendy

Beth

Kabul

Mary Kay D. Andersen

Tên hai phần

Mary Kay

Andersen

Paula Barreto de Mattos

Họ có ba phần

Paula

Barreto de Mattos

James van Eaton

Họ có hai phần

James

van Eaton

Bacon Jr., Dan K.

Họ và hậu tố trước tiên, với dấu phẩy

Dan

Bacon

Jr.

Gary Altman III

Với hậu tố

Gary

Altman

III

Ông Ryan Ihrig

Có tiền tố

Ryan

Ihrig

Julie Taft-Rider

Họ gạch nối từ

Julie

Taft-Rider

Lưu ý:Trong đồ họa ở các ví dụ sau đây, phần tô sáng trong tên đầy đủ sẽ cho thấy ký tự mà công thức SEARCH khớp đang tìm kiếm.

Ví dụ 1: Tách Jeff và Smith

Ví dụ này phân tách hai thành phần: tên và họ. Một khoảng trắng đơn sẽ phân tách hai tên.

Sao chép các ô trong bảng và dán vào trang Excel tính ở ô A1. Công thức bạn thấy ở bên trái sẽ được hiển thị để tham chiếu, trong khi công thức Excel sẽ tự động chuyển đổi công thức ở bên phải thành kết quả thích hợp.

Gợi ý Trước khi dán dữ liệu vào trang tính, hãy đặt độ rộng cột của cột A và B thành 250.

Tên ví dụ

Mô tả

Jeff Smith

Không có tên đệm

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

Tên

Tên bắt đầu bằng ký tự đầu tiên trong chuỗi (J) và kết thúc ở ký tự thứ năm (khoảng trắng). Công thức này sẽ cho ra năm ký tự trong ô A2, bắt đầu từ bên trái.

Dùng hàm SEARCH để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ bên trái.
Họ

Họ bắt đầu ở khoảng trắng, năm ký tự từ bên phải và kết thúc ở ký tự cuối cùng ở bên phải (h). Công thức này sẽ trích xuất năm ký tự trong ô A2, bắt đầu từ bên phải.

Dùng các hàm SEARCH và LEN để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ bên trái. (5)
Đếm tổng chiều dài của chuỗi văn bản và sau đó trừ số ký tự ở bên trái của khoảng trắng đầu tiên, như được thấy ở bước 1.

Ví dụ 2: Eric S. Kurjan: Trích xuất tên và họ, cộng với tên viết tắt đệm

Ví dụ này sử dụng tên, tên đệm và họ. Một khoảng trắng sẽ phân tách từng cấu phần tên.

Gợi ý Trước khi dán dữ liệu vào trang tính, hãy đặt độ rộng cột của cột A và B thành 250.

Tên ví dụ

Mô tả

Eric S. Kurjan

Một tên viết tắt giữa

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (ban đầu ở giữa)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Công thức

Kết quả Trực tiếp (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Tên

Tên bắt đầu bằng ký tự đầu tiên từ bên trái (E) và kết thúc ở ký tự thứ năm (khoảng trắng đầu tiên). Công thức này trích xuất năm ký tự đầu tiên trong ô A2, bắt đầu từ bên trái.

Dùng hàm SEARCH để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ bên trái. (5)
Tên đệm

Tên đệm bắt đầu ở vị trí ký tự thứ sáu (S) và kết thúc ở vị trí thứ tám (khoảng trắng thứ hai). Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ hai.

Công thức này trích xuất ba ký tự, bắt đầu từ vị trí thứ sáu.

Dùng hàm SEARCH để tìm giá trị start_num:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (5).
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (S). Vị trí số này là vị trí bắt đầu của tên đệm. (5 + 1 = 6)

Dùng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (5)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (S). Kết quả là số ký tự mà tại đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ hai. (5 + 1 = 6)
Tìm kiếm thể hiện khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (S) được tìm thấy ở bước 4. Số ký tự này là vị trí kết thúc của tên đệm. (8)
Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (5)
Lấy số ký tự của khoảng trắng thứ hai được tìm thấy ở bước 5 và trừ số ký tự của khoảng trắng đầu tiên được tìm thấy ở bước 6. Kết quả là số các ký tự mà MID trích xuất từ chuỗi văn bản bắt đầu từ vị trí thứ sáu được tìm thấy ở bước 2. (8 5 = 3)
Họ

Họ bắt đầu sáu ký tự từ bên phải (K) và kết thúc ở ký tự đầu tiên từ bên phải (n). Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ hai và thứ ba (nằm ở vị trí thứ năm và thứ tám từ bên trái).

Công thức này trích xuất sáu ký tự trong ô A2, bắt đầu từ bên phải.
Dùng hàm LEN và hàm SEARCH được lồng vào để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (5)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (S). Kết quả là số ký tự mà tại đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ hai. (5 + 1 = 6)
Tìm kiếm thể hiện khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (S) được tìm thấy ở bước 2. Số ký tự này là vị trí kết thúc của tên đệm. (8)
Đếm tổng chiều dài của chuỗi văn bản trong A2, rồi trừ số ký tự từ bên trái đến thể hiện khoảng trắng thứ hai được tìm thấy ở bước 3. Kết quả là số ký tự được trích xuất từ bên phải của họ tên. (14 8 = 6).

Ví dụ 3: Janaina B. G. Bueno

Dưới đây là ví dụ về cách trích xuất hai tên viết tắt đệm. Phiên bản khoảng trắng đầu tiên và thứ ba phân tách các cấu phần tên.

Gợi ý Trước khi dán dữ liệu vào trang tính, hãy đặt độ rộng cột của cột A và B thành 250.

Tên ví dụ

Mô tả

Janaina B. G. Bueno

Hai tên viết tắt giữa

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (tên viết tắt đệm)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

Công thức

Kết quả Trực tiếp (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Tên

Tên bắt đầu bằng ký tự đầu tiên từ bên trái (J) và kết thúc ở ký tự thứ tám (khoảng trắng đầu tiên). Công thức này trích xuất tám ký tự đầu tiên trong ô A2, bắt đầu từ bên trái.

Dùng hàm SEARCH để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (8)
Tên đệm

Tên đệm bắt đầu ở vị trí thứ chín (B) và kết thúc ở vị trí thứ mười bốn (khoảng trắng thứ ba). Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ nhất, thứ hai và thứ ba ở vị trí thứ tám, thứ mười một và thứ mười bốn.

Công thức này trích xuất năm ký tự, bắt đầu từ vị trí thứ chín.

Dùng hàm SEARCH để tìm giá trị start_num:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (8)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (B). Vị trí số này là vị trí bắt đầu của tên đệm. (8 + 1 = 9)

Dùng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (8)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (B). Kết quả là số ký tự mà tại đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ hai. (8 + 1 = 9)
Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ chín (B) được tìm thấy ở bước 4. (11).
Cộng 1 để có vị trí của ký tự sau khoảng trắng thứ hai (G). Số ký tự này là vị trí bắt đầu tại vị trí mà bạn muốn bắt đầu tìm kiếm khoảng trắng thứ ba. (11 + 1 = 12)
Tìm kiếm khoảng trắng thứ ba trong A2, bắt đầu từ vị trí thứ mười hai được tìm thấy ở bước 6. (14)
Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2. (8)
Lấy số ký tự của khoảng trắng thứ ba được tìm thấy ở bước 7 và trừ số ký tự của khoảng trắng đầu tiên được tìm thấy ở bước 6. Kết quả là số các ký tự mà MID trích xuất từ chuỗi văn bản bắt đầu từ vị trí thứ chín được tìm thấy ở bước 2.
Họ

Họ bắt đầu năm ký tự từ bên phải (B) và kết thúc ở ký tự đầu tiên từ bên phải (o). Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng đầu tiên, thứ hai và thứ ba.

Công thức này trích xuất năm ký tự trong ô A2, bắt đầu từ bên phải tên đầy đủ.

Dùng các hàm SEARCH và LEN được lồng để tìm giá trị cho giá trị num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (8)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (B). Kết quả là số ký tự mà tại đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ hai. (8 + 1 = 9)
Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ chín (B) được tìm thấy ở bước 2. (11)
Cộng 1 để có vị trí của ký tự sau khoảng trắng thứ hai (G). Số ký tự này là vị trí bắt đầu mà tại đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ ba. (11 + 1 = 12)
Tìm kiếm khoảng trắng thứ ba trong A2, bắt đầu từ vị trí thứ mười hai (G) được tìm thấy ở bước 6. (14)
Đếm tổng chiều dài của chuỗi văn bản trong A2, rồi trừ số ký tự từ bên trái tới khoảng trắng thứ ba được tìm thấy ở bước 5. Kết quả là số ký tự được trích xuất từ bên phải của họ tên. (19 - 14 = 5)

Ví dụ 4: Kabul, Wendy Beth

Trong ví dụ này, họ đứng trước tên và tên đệm xuất hiện ở phần cuối. Dấu phẩy đánh dấu phần cuối của họ và một khoảng trắng phân tách từng cấu phần tên.

Gợi ý Trước khi dán dữ liệu vào trang tính, hãy đặt độ rộng cột của cột A và B thành 250.

Tên ví dụ

Mô tả

Kabul, Wendy Beth

Họ trước tiên, với dấu phẩy

Công thức

Kết quả (tên)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Công thức

Kết quả (tên đệm)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Công thức

Kết quả Trực tiếp (họ)

'=LEFT(A2, SEARCH(" ",A2,1)-2)

=LEFT(A2, SEARCH(" ",A2,1)-2)

Tên

Tên bắt đầu bằng ký tự thứ bảy từ bên trái (W) và kết thúc ở ký tự thứ mười hai (khoảng trắng thứ hai). Vì tên xuất hiện ở giữa họ tên, bạn cần phải dùng hàm MID để trích xuất tên.

Công thức này trích xuất sáu ký tự, bắt đầu từ vị trí thứ bảy.

Dùng hàm SEARCH để tìm giá trị start_num:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (6)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (W). Vị trí số này là điểm bắt đầu của tên. (6 + 1 = 7)

Dùng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (6)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (W). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (6 + 1 = 7)

Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ bảy (W) được tìm thấy ở bước 4. (12)
Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (6)
Lấy số ký tự của khoảng trắng thứ hai được tìm thấy ở bước 5 và trừ số ký tự của khoảng trắng đầu tiên được tìm thấy ở bước 6. Kết quả là số các ký tự mà MID trích xuất từ chuỗi văn bản bắt đầu ở vị trí thứ bảy được tìm thấy ở bước 2. (12 - 6 = 6)
Tên đệm

Tên đệm bắt đầu ở bốn ký tự từ bên phải (B) và kết thúc ở ký tự đầu tiên từ bên phải (h). Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ nhất và thứ hai ở vị trí thứ sáu và thứ mười hai từ bên trái.

Công thức này trích xuất bốn ký tự, bắt đầu từ bên phải.

Dùng các hàm SEARCH và LEN đã lồng để tìm giá trị cho start_num:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (6)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (W). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (6 + 1 = 7)
Tìm kiếm thể hiện khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ bảy (W) được tìm thấy ở bước 2. (12)
Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến thể hiện khoảng trắng thứ hai được thấy ở bước 3. Kết quả là số ký tự được trích xuất từ bên phải của họ tên. (16 - 12 = 4)
Họ

Họ bắt đầu bằng ký tự đầu tiên từ bên trái (K) và kết thúc ở ký tự thứ tư (n). Công thức này trích xuất bốn ký tự, bắt đầu từ bên trái.

Dùng hàm SEARCH để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (6)
Trừ 2 để có vị trí số của ký tự cuối cùng của họ (n). Kết quả là số ký tự bạn muốn hàm LEFT trích xuất . (6 - 2 =4)

Ví dụ 5: Mary Kay D. Andersen

Ví dụ này dùng tên có hai phần, Mary Kay. Các khoảng trắng thứ hai và thứ ba phân tách từng cấu phần tên.

Gợi ý Trước khi dán dữ liệu vào trang tính, hãy đặt độ rộng cột của cột A và B thành 250.

Tên ví dụ

Mô tả

Mary Kay D. Andersen

Tên hai phần

Công thức

Kết quả (tên)

LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Công thức

Kết quả (ban đầu ở giữa)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Công thức

Kết quả Trực tiếp (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Tên

Tên bắt đầu bằng ký tự đầu tiên từ bên trái và kết thúc ở ký tự thứ chín (khoảng trắng thứ hai). Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ hai từ bên trái.

Công thức này trích xuất chín ký tự, bắt đầu từ bên trái.

Dùng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (5)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (K). Kết quả là số ký tự mà tại đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ hai. (5 + 1 = 6)
Tìm kiếm thể hiện khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (K) được tìm thấy ở bước 2. Kết quả là số ký tự left trích xuất từ chuỗi văn bản. (9)
Tên đệm

Tên đệm bắt đầu ở vị trí thứ mười (D) và kết thúc ở vị trí thứ mười hai (khoảng trắng thứ ba). Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng đầu tiên, thứ hai và thứ ba.

Công thức này trích xuất hai ký tự từ giữa, bắt đầu từ vị trí thứ mười.

Sử dụng các hàm SEARCH được lồng để tìm giá trị cho start_num:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (5)
Cộng 1 để lấy ký tự sau khoảng trắng đầu tiên (K). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (5 + 1 = 6)
Tìm kiếm vị trí của thể hiện khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (K) được tìm thấy ở bước 2. Kết quả là số ký tự LEFT trích xuất từ bên trái. (9)
Cộng 1 để lấy ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí bắt đầu của tên đệm. (9 + 1 = 10)

Dùng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của ký tự sau khoảng trắng thứ hai (D). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ ba. (10)
Tìm kiếm vị trí số của khoảng trắng thứ ba trong A2, bắt đầu từ bên trái. Kết quả là vị trí kết thúc của tên đệm. (12)
Tìm kiếm vị trí số của ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí đầu của tên đệm. (10)
Lấy số ký tự của khoảng trắng thứ ba, được tìm thấy ở bước 6, và trừ số ký tự của "D", được tìm thấy ở bước 7. Kết quả là số các ký tự mà MID trích xuất từ chuỗi văn bản bắt đầu từ vị trí thứ mười được tìm thấy ở bước 4. (12 - 10 = 2)
Họ

Họ bắt đầu tám ký tự từ bên phải. Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ nhất, thứ hai và thứ ba ở vị trí thứ năm, thứ chín và thứ mười hai.

Công thức này trích xuất tám ký tự từ bên phải.

Dùng các hàm SEARCH và LEN được lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (5)
Cộng 1 để lấy ký tự sau khoảng trắng đầu tiên (K). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng. (5 + 1 = 6)
Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (K) được tìm thấy ở bước 2. (9)
Cộng 1 để có vị trí của ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí bắt đầu của tên đệm. (9 + 1 = 10)
Tìm kiếm vị trí số của khoảng trắng thứ ba trong A2, bắt đầu từ bên trái. Kết quả là vị trí kết thúc của tên đệm. (12)
Đếm tổng chiều dài của chuỗi văn bản trong A2, rồi trừ số ký tự từ bên trái tới khoảng trắng thứ ba được tìm thấy ở bước 5. Kết quả là số ký tự được trích xuất từ bên phải của họ tên. (20 - 12 = 8)

Ví dụ 6: Paula Barreto de Mattos

Ví dụ này dùng họ có ba phần: Barreto de Mattos. Khoảng trắng đầu tiên đánh dấu phần kết thúc của tên và phần đầu của họ.

Gợi ý Trước khi dán dữ liệu vào trang tính, hãy đặt độ rộng cột của cột A và B thành 250.

Tên ví dụ

Mô tả

Paula Barreto de Mattos

Họ có ba phần

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (họ)

RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

Tên

Tên bắt đầu bằng ký tự đầu tiên từ bên trái (P) và kết thúc ở ký tự thứ sáu (khoảng trắng đầu tiên). Công thức này trích xuất sáu ký tự từ bên trái.

Sử dụng hàm Search để tìm giá trị cho các giá num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)
Họ

Họ bắt đầu mười bảy ký tự từ bên phải (B) và kết thúc bằng ký tự đầu tiên từ bên phải (s). Công thức này trích xuất bảy ký tự từ bên phải.

Dùng hàm LEN và SEARCH để tìm giá trị cho các giá num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)
Đếm tổng độ dài của chuỗi văn bản trong A2, rồi trừ số ký tự từ bên trái lên đến khoảng trắng đầu tiên, được tìm thấy ở bước 1. Kết quả là số ký tự được trích xuất từ bên phải của họ tên. (23 - 6 = 17)

Ví dụ 7: James van Eaton

Ví dụ này sử dụng họ có hai phần: van Eaton. Khoảng trắng đầu tiên đánh dấu phần kết thúc của tên và phần đầu của họ.

Gợi ý Trước khi dán dữ liệu vào trang tính, hãy đặt độ rộng cột của cột A và B thành 250.

Tên ví dụ

Mô tả

James van Eaton

Họ có hai phần

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

Tên

Tên bắt đầu bằng ký tự đầu tiên từ bên trái (J) và kết thúc ở ký tự thứ tám (khoảng trắng đầu tiên). Công thức này trích xuất sáu ký tự từ bên trái.

Dùng hàm SEARCH để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)
Họ

Họ bắt đầu bằng ký tự thứ chín từ bên phải (v) và kết thúc ở ký tự đầu tiên từ bên phải (n). Công thức này trích xuất chín ký tự từ bên phải của họ tên.

Dùng hàm LEN và SEARCH để tìm giá trị cho các giá num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)
Đếm tổng độ dài của chuỗi văn bản trong A2, rồi trừ số ký tự từ bên trái lên đến khoảng trắng đầu tiên, được tìm thấy ở bước 1. Kết quả là số ký tự được trích xuất từ bên phải của họ tên. (15 - 6 = 9)

Ví dụ 8: Bacon Jr., Dan K.

Trong ví dụ này, họ được đặt tên trước tiên, tiếp theo là hậu tố. Dấu phẩy phân tách họ và hậu tố với tên và tên đệm.

Gợi ý Trước khi dán dữ liệu vào trang tính, hãy đặt độ rộng cột của cột A và B thành 250.

Tên ví dụ

Mô tả

Bacon Jr., Dan K.

Họ và hậu tố trước tiên, với dấu phẩy

Công thức

Kết quả (tên)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Công thức

Kết quả (ban đầu ở giữa)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Công thức

Kết quả (họ)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (hậu tố)

'=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

Tên

Tên bắt đầu bằng ký tự thứ mười hai (D) và kết thúc bằng ký tự thứ mười lăm (khoảng trắng thứ ba). Công thức này trích xuất ba ký tự, bắt đầu từ vị trí thứ mười hai.

Sử dụng các hàm SEARCH được lồng để tìm giá trị cho start_num:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)
Cộng 1 để lấy ký tự sau khoảng trắng đầu tiên (J). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (6 + 1 = 7)
Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ bảy (J), được tìm thấy ở bước 2. (11)
Cộng 1 để lấy ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí bắt đầu của tên. (11 + 1 = 12)

Dùng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của ký tự sau khoảng trắng thứ hai (D). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ ba. (12)
Tìm kiếm vị trí số của khoảng trắng thứ ba trong A2, bắt đầu từ bên trái. Kết quả là vị trí kết thúc của tên. (15)
Tìm kiếm vị trí số của ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí đầu của tên. (12)
Lấy số ký tự của khoảng trắng thứ ba, được tìm thấy ở bước 6, và trừ số ký tự của "D", được tìm thấy ở bước 7. Kết quả là số các ký tự mà MID trích xuất từ chuỗi văn bản bắt đầu từ vị trí thứ mười hai, được tìm thấy ở bước 4. (15 - 12 = 3)
Tên đệm

Tên đệm bắt đầu bằng ký tự thứ hai từ bên phải (K). Công thức này trích xuất hai ký tự từ bên phải.

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)
Cộng 1 để lấy ký tự sau khoảng trắng đầu tiên (J). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (6 + 1 = 7)
Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ bảy (J), được tìm thấy ở bước 2. (11)
Cộng 1 để lấy ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí bắt đầu của tên. (11 + 1 = 12)
Tìm kiếm vị trí số của khoảng trắng thứ ba trong A2, bắt đầu từ bên trái. Kết quả là vị trí kết thúc của tên đệm. (15)
Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến khoảng trắng thứ ba, được tìm thấy ở bước 5. Kết quả là số ký tự được trích xuất từ bên phải của họ tên. (17 - 15 = 2)
Họ

Họ bắt đầu ở ký tự đầu tiên từ bên trái (B) và kết thúc ở ký tự thứ sáu (khoảng trắng đầu tiên). Do đó, công thức sẽ trích xuất sáu ký tự từ bên trái.

Dùng hàm SEARCH để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)
Suffix

Hậu tố bắt đầu ở ký tự thứ bảy từ bên trái (J) và kết thúc ở ký tự thứ chín từ bên trái (.). Công thức này trích xuất ba ký tự, bắt đầu từ ký tự thứ bảy.

Dùng hàm SEARCH để tìm giá trị start_num:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)
Cộng 1 để lấy ký tự sau khoảng trắng đầu tiên (J). Kết quả là vị trí bắt đầu của hậu tố. (6 + 1 = 7)

Dùng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)
Cộng 1 để có vị trí số của ký tự sau khoảng trắng đầu tiên (J). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (7)
Tìm kiếm vị trí số của khoảng trắng thứ hai trong A2, bắt đầu từ ký tự thứ bảy được tìm thấy ở bước 4. (11)
Trừ 1 từ số ký tự của khoảng trắng thứ hai được tìm thấy ở bước 4 để có số ký tự là ",". Kết quả là vị trí kết thúc của hậu tố. (11 - 1 = 10)
Tìm kiếm vị trí số của khoảng trắng đầu tiên. (6)
Sau khi tìm khoảng trắng đầu tiên, hãy thêm 1 để tìm ký tự tiếp theo (J), cũng có trong bước 3 và 4. (7)
Lấy số ký tự "," được tìm thấy ở bước 6, và trừ số ký tự của "J", được tìm thấy ở bước 3 và 4. Kết quả là số các ký tự mà MID trích xuất từ chuỗi văn bản bắt đầu ở vị trí thứ bảy, được tìm thấy ở bước 2. (10 - 7 = 3)

Ví dụ 9: Gary Altman III

Trong ví dụ này, tên nằm ở đầu chuỗi và hậu tố ở cuối, vì vậy bạn có thể dùng các công thức tương tự như Ví dụ 2: Dùng hàm LEFT để trích xuất tên, hàm MID để trích xuất họ và hàm RIGHT để trích xuất hậu tố.

Gợi ý Trước khi dán dữ liệu vào trang tính, hãy đặt độ rộng cột của cột A và B thành 250.

Tên ví dụ

Mô tả

Gary Altman III

Họ và tên có hậu tố

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (họ)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Công thức

Kết quả (hậu tố)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Tên

Tên bắt đầu từ ký tự đầu tiên từ bên trái (G) và kết thúc ở ký tự thứ năm (khoảng trắng đầu tiên). Do đó, công thức sẽ trích xuất năm ký tự từ bên trái tên đầy đủ.

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (5)
Họ

Họ bắt đầu từ ký tự thứ sáu từ bên trái (A) và kết thúc ở ký tự thứ mười một (khoảng trắng thứ hai). Công thức này gồm có việc lồng hàm SEARCH để tìm vị trí của các khoảng trắng.

Công thức này trích xuất sáu ký tự từ giữa, bắt đầu từ ký tự thứ sáu.

Dùng hàm SEARCH để tìm giá trị start_num:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (5)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (A). Kết quả là vị trí bắt đầu của họ. (5 + 1 = 6)

Dùng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (5)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (A). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (5 + 1 = 6)
Tìm kiếm vị trí số của khoảng trắng thứ hai trong A2, bắt đầu từ ký tự thứ sáu được tìm thấy ở bước 4. Số ký tự này là vị trí kết thúc của họ. (12)
Tìm kiếm vị trí số của khoảng trắng đầu tiên. (5)
Thêm 1 để tìm vị trí số của ký tự sau khoảng trắng đầu tiên (A), cũng có trong bước 3 và 4. (6)
Lấy số ký tự của khoảng trắng thứ hai, được tìm thấy ở bước 5, sau đó trừ số ký tự của "A", được tìm thấy trong bước 6 và 7. Kết quả là số các ký tự mà MID trích xuất từ chuỗi văn bản, bắt đầu từ vị trí thứ sáu, được tìm thấy ở bước 2. (12 - 6 = 6)
Suffix

Hậu tố bắt đầu ba ký tự từ bên phải. Công thức này gồm có việc lồng hàm SEARCH để tìm vị trí của các khoảng trắng.

Dùng các hàm SEARCH và LEN được lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (5)
Cộng 1 để lấy ký tự sau khoảng trắng đầu tiên (A). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (5 + 1 = 6)
Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (A), được tìm thấy ở bước 2. (12)
Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến khoảng trắng thứ hai, được tìm thấy ở bước 3. Kết quả là số ký tự được trích xuất từ bên phải của họ tên. (15 - 12 = 3)

Ví dụ 10: Ông Ryan Ihrig

Trong ví dụ này, tên đầy đủ có tiền tố đứng trước và bạn dùng công thức tương tự như Ví dụ 2: hàm MID để trích xuất tên, hàm RIGHT để trích xuất họ.

Gợi ý Trước khi dán dữ liệu vào trang tính, hãy đặt độ rộng cột của cột A và B thành 250.

Tên ví dụ

Mô tả

Ông Ryan Ihrig

Có tiền tố

Công thức

Kết quả (tên)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Công thức

Kết quả (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Tên

Tên bắt đầu từ ký tự thứ năm từ bên trái (R) và kết thúc ở ký tự thứ chín (khoảng trắng thứ hai). Công thức lồng hàm SEARCH để tìm vị trí của các khoảng trắng. Nó trích xuất bốn ký tự, bắt đầu từ vị trí thứ năm.

Sử dụng hàm SEARCH để tìm giá trị cho giá start_num:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (4)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (R). Kết quả là vị trí bắt đầu của tên. (4 + 1 = 5)

Sử dụng hàm SEARCH được lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (4)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (R). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (4 + 1 = 5)
Tìm kiếm vị trí số của khoảng trắng thứ hai trong A2, bắt đầu từ ký tự thứ năm, được tìm thấy trong bước 3 và 4. Số ký tự này là vị trí kết thúc của tên. (9)
Tìm kiếm khoảng trắng đầu tiên. (4)
Thêm 1 để tìm vị trí số của ký tự sau khoảng trắng đầu tiên (R), cũng có trong bước 3 và 4. (5)
Lấy số ký tự của khoảng trắng thứ hai, được tìm thấy ở bước 5, sau đó trừ số ký tự của "R", được tìm thấy ở bước 6 và 7. Kết quả là số các ký tự mà MID trích xuất từ chuỗi văn bản, bắt đầu từ vị trí thứ năm được tìm thấy ở bước 2. (9 - 5 = 4)
Họ

Họ bắt đầu từ bên phải năm ký tự. Công thức này gồm có việc lồng hàm SEARCH để tìm vị trí của các khoảng trắng.

Dùng các hàm SEARCH và LEN được lồng để tìm giá trị cho num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (4)
Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (R). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (4 + 1 = 5)
Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ năm (R), được tìm thấy ở bước 2. (9)
Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến khoảng trắng thứ hai, được tìm thấy ở bước 3. Kết quả là số ký tự được trích xuất từ bên phải của họ tên. (14 - 9 = 5)

Ví dụ 11: Julie Taft-Rider

Ví dụ này sử dụng họ được gạch nối. Một khoảng trắng sẽ phân tách từng cấu phần tên.

Gợi ý Trước khi dán dữ liệu vào trang tính, hãy đặt độ rộng cột của cột A và B thành 250.

Tên ví dụ

Mô tả

Julie Taft-Rider

Họ gạch nối từ

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

Tên

Tên bắt đầu từ ký tự đầu tiên từ bên trái và kết thúc ở vị trí thứ sáu (khoảng trắng đầu tiên). Công thức này trích xuất sáu ký tự từ bên trái.

Sử dụng hàm SEARCH để tìm giá trị của các num_chars:

Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)
Họ

Toàn bộ họ bắt đầu mười ký tự từ bên phải (T) và kết thúc ở ký tự đầu tiên từ bên phải (r).

Dùng hàm LEN và SEARCH để tìm giá trị cho các giá num_chars:

Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (6)
Đếm tổng chiều dài của chuỗi văn bản được trích xuất, rồi trừ số ký tự từ bên trái lên đến khoảng trắng đầu tiên, được tìm thấy ở bước 1. (16 - 6 = 10)

Tách văn bản thành cột khác nhau với Trình hướng dẫn Chuyển đổi Văn bản thành Cột

Cách tách số trong 1 ô Excel

Ví dụ 1: Tách Jeff và Smith

Ví dụ 2: Eric S. Kurjan: Trích xuất tên và họ, cộng với tên viết tắt đệm

Ví dụ 3: Janaina B. G. Bueno

Ví dụ 4: Kabul, Wendy Beth

Ví dụ 5: Mary Kay D. Andersen

Ví dụ 6: Paula Barreto de Mattos

Ví dụ 7: James van Eaton

Ví dụ 8: Bacon Jr., Dan K.

Ví dụ 9: Gary Altman III

Ví dụ 10: Ông Ryan Ihrig

Ví dụ 11: Julie Taft-Rider

Video liên quan

نموذج الاتصال